STM32启动文件进入main函数之前做了什么

我斑愿称你为最强（STM32启动文件分析）

1）奥利给，肝了：


Stack_Size EQU 0x400


AREA STACK, NOINIT, READWRITE, ALIGN=3
Stack_Mem SPACE Stack_Size
__initial_sp

; Heap Configuration
; Heap Size (in Bytes) <0x0-0xFFFFFFFF:8>
;


Heap_Size EQU 0x200


AREA HEAP, NOINIT, READWRITE, ALIGN=3
__heap_base
Heap_Mem SPACE Heap_Size
__heap_limit


PRESERVE8
THUMB

重头开始看起：汇编程序和其他程序一样，并不是一上来就是代码段，可能会有一些定义，声明之类的东西。
EQU是一个伪指令(伪指令是没有对应的机器码的)，就是说明Stack_Size等于0x400,就是通知编译器，这个符号的值为0x400。
这里补充一点 伪指令的定义：伪指令没有对应的机器代码，并不像指令语句那样由CPU来执行，是由汇编器在汇编源程序时执行的。
主要是完成变量定义，存储器分配，指示段定义，段分配，段结束等。

AREA代表的是TheAREAdirective instructs the assembler to assemble a new code or data section.
AREA STACK, NOINIT, READWRITE, ALIGN=3
AREA就是告诉汇编器汇编一个代码段或数据段。后面从参数用于告诉汇编器要汇编段的信息。
STACK说明段的名字，就是栈；NOINIT不初始化，READWRITE可读可写，ALIGN说明是8(2^3）字节对齐。
这里主要说明一下 字节对齐的概念，8字节对齐的意思就是说该段所在的 起始地址的低三位为0。

SPACE 也是个伪指令，前面AREA说明要汇编一个栈段，那么后面要说明该栈段的大小。SPACE告诉汇编器栈段的大小为Stack_Size即0x400,Stack_Mem是什么意思呢，他是一个可选项（就是可写，可不写）他与指令中的标号是一个意思，代表的是汇编地址；__initial_sp代表的是栈的结束地址，就是栈顶地址。
如果想看一下__initial_sp到底是什么东西呢，涉及到一个.map文件，里面有所有符号的定义

要想讲清楚.map文件中的内容，涉及到 的还是挺多的，要了解可执行目标文件的格式、编译等内容，还是有点篇幅，这里暂时不讲，不理解的话没关系，暂时只需要清楚上面的内容即可。
可以发现__initial_sp的值就是0x20000410,这里正好对应着程序在运行时SRAM区的栈顶地址。这里面需要了解的就是程序在存储时是存储在flash中，运行时会将RW数据区(有初值的全局变量)移到SRAM中,并添加ZI数据区。（ZI数据区包含有初始化为0 的全局变量（类似于bss段），以及堆，以及栈段）,如何看各个段的大小呢？

在使用fromelf工具查看.axf文件（可执行文件）时，就可以看到段的大小，可以发现RW数据区与ZI数据区的bss段所占的空间为16字节（0x10）,所以前面STACK的值为0x20000010

在启动文件中明明有堆空间的创建（程序紧接着栈后面），而实际的却没有堆空间，这是怎么回事呢？这一点与armlink中的编译器优化相关。编译器优化看样子是很高深的概念，其实就是在不影响正常程序功能的情况下，让程序更好，就是说可能会让程序占据更小的空间，比如这里的堆，因为没有使用动态内存分配，所以有和没有是一样的，为了减少SRAM空间的消耗，就不给他分配空间。这对资源少的嵌入式设备来说，是有一定帮助的。

接下来就是汇编一个名叫RESET的只读数据区AREA RESET, DATA, READONLY。

主要说明就是EXPORT

TheEXPORTdirective declares a symbol that can be used by the linker to resolve symbol references in separate object and library files.GLOBALis a synonym forEXPORT.
EXPORT指令就是声明一个标号，什么样的标号，被连接器使用来解析符号在不同目标与库文件的引用。
UseEXPORTto give code in other files access to symbols in the current file.
根据上面这句话的意思就是说，在当前文件中，对其他文件的的 符号使用标号，就可以访问该标号。

三个标号的具体值是多少呢？

(这里有我自己想无意中思考的问题，就是在任何代码文件中，并没有指定这些标号的值，到底这些标号是如何被赋予这些特定的值的呢？后面学习了程序的可执行文件，推测大概是这样的，当编译器在生成可执行文件映像的过程中，会将映像与程序的存储的物理地址联系起来，这个在物理地址编译之前是给了的，最后根据映像在物理地址的位置，上面这些标号的值就建立起来了。这里只是记录个人的想法，可略过，继续下面的内容)
这里很奇怪，这里向量表的结束地址为0x08000130，但是在cortex-M3编程手册中的（PM0056）中向量表的结束地址会大一点，如下图所示：

暂时不是特别清楚，为什么会这样，但是并不影响阅读与理解，先放这里。
DCD命令主要说明的就是分配内存空间，那这时会不会有人像我一样，前面不是有一个叫SPACE的吗？不也是分配内存空间，两者有什么区别呢？
DCD开辟的空间支持4字节对齐，而且可以初始化，就是给开辟的空间赋值DCD __initial_sp.
SPACE开辟的空间是不支持字节对齐，如果想让字节对齐，后面必须跟一条语句。下面的英文是官方的解释。而且用这条语句开辟的空间是初始化为0的。这就是与DCD指令的区别
Use theALIGNdirective to align any code following aSPACEorFILLdirective

整个向量表除了第一项存放的栈顶地址，其余各项存放的是函数名。**函数名就是该函数（代码块）所在内存的起始地址。**以其中一项为例说明：

这个Reset_Handler的值就为0x08000145，本质上就是地址。

接下来就是代码段了AREA |.text|, CODE, READONLY

; Reset handler
Reset_Handler PROC
EXPORT Reset_Handler [WEAK]
IMPORT __main
IMPORT SystemInit
LDR R0, =SystemInit
BLX R0
LDR R0, =__main
BX R0
ENDP

上面就是复位的异常处理函数，当STM32上电时,PC指针(R15)被赋予的初值为复位向量的值，也就是复位异常处理函数。堆栈指针MSP被赋值为向量表的第一项（刚上电时是特权级），也就__initial_sp。然后程序就来执行这里的代码。
PEOC与ENDP是固定用法，代表的是过程的开始与结束。有点汇编基础的比较好理解。

这里EXPORT后面加了一个[WEAK],代表什么意思呢？官方的解释是这样的。

如果能在其他源文件中找到一个相同的符号，那么那个在其他源文件的符号的优先级将高于这个。也就是说你如果自定义了复位函数，那么系统会执行你自定义的复位函数。

IMPORT说明是什么含义呢？说明后面的标号不是本文件定义的，引用其他文件定义的标号。连接器链接时会帮你找到它真正的位置。

这里先埋下一个伏笔，就是说通过反汇编代码去深入的学习__main函数。因为直接跳到__main函数会发现没有定义。记住非常关键点就是0x8000131。正好在向量表的下面。

SystemInit就是正常的c语言函数。

LDR指令，官方解释：Load addresses to a register using LDR Rd, =label,就是加载地址到寄存器中。简单。
BLX指令, 官方解释：

总结就是，保存下条指令的地址到LR中,跳转到分支去执行，还会切换处理器的状态，但是Cortex-M3只有Thumb态，所以这里并不会切换。所谓Thumb态，还有一种ARM态指的是处理器识别不同 的指令集，像ARM9之类的处理器，存在两种状态的。

BX指令与BLX指令类似（BL与BLX类似），就是不保存返回地址。

这里有没有发现一个奇怪的地方，就是SystemInit的值是0x08000abd，（来自工程的.map文件）但是反汇编出来的，真正的地址是0x08000abc,差了1，为什么会差了1呢？又验证了其他几个函数名，发现都是相差1,我曾经看过这么一段话，就是在更新PC（R15）寄存器时，会将PC指针的LSB置1，来表示Thumb状态，对于高级编程语言（包括C和C++），编译器会自动将跳转目标的LSB置位。正好对应到这里的相差1。

这里SystemInit只有一句话，就是跳转至lr中的地址，实际的C语言是：

void SystemInit (void)
{
#if defined(STM32F100xE) || defined(STM32F101xE) || defined(STM32F101xG) || defined(STM32F103xE) || defined(STM32F103xG)
#ifdef DATA_IN_ExtSRAM
SystemInit_ExtMemCtl();
#endif /* DATA_IN_ExtSRAM */
#endif


/* Configure the Vector Table location -------------------------------------*/
#if defined(USER_VECT_TAB_ADDRESS)
SCB->VTOR = VECT_TAB_BASE_ADDRESS | VECT_TAB_OFFSET; /* Vector Table Relocation in Internal SRAM. */
#endif /* USER_VECT_TAB_ADDRESS */
}

在本工程中，宏DATA_IN_ExtSRAM与宏USER_VECT_TAB_ADDRESS都没有定义，所以说这个函数什么也不执行，当遇到}时，就相当于遇到返回指令，在CORTEX-M中，因为有链接寄存器，估计就将}直接编译成，跳转到链接寄存器的语句了。

接下来，重头戏就来了，就是这个__main函数。

前面提到了__main函数的地址，直接来到那里的第一条语句。加载sp寄存器的内容为__lit__00000000。

然后是跳转到标号__scatterload处去执行。

第一句，将地址PC+24所对应的内容加载到到r4寄存器中。

这里发现一个很奇怪的现象,什么现象呢？无论我怎么算，都没有办法算到pc+24(0x18)=0x80001a8，按照正常的逻辑来说，pc的值为下一条指令的地址，但是下一条指令的地址为0x0800018e,加上0x18后就等于0x080001a6,反过来算，将0x80001a8-0x18
结果为0x08000190,同样的方法计算下一条指令0x0800018e，这两条指令的真实PC值都是0x08000190,这和PC指向下一条指令的地址是矛盾的。
然后想用keil5中调试看一下，结果如下图所示：

根据调试的PC指针的变化，是符合PC指向将要执行语句的地址，当执行这条语句时，PC指向的是下一条指令的地址。（自动变化的），但是这明显就是冲突。到底是哪里出了问题，后来在< >的第91页中说了，因为流水线的结构，PC的值并非LDR指令的地址。暂时我的理解是因为流水线，还有什么分支预测，乱序执行，导致真正PC指针的变化，并不循规蹈矩，但是keil5中PC寄存器的变化确实循规蹈矩的，个人的推测，应该是PC寄存器中的PC值不是真实值，只不过是方便我们看程序执行到哪里了。当然，这完全是个人想法，可能完全是错的，如果有更好的想法，欢迎分享。

赋值完r4、r5后。就跳转到0x080001a0处执行。

这里说明一个问题啊，就是在调试的时候，按照正常的分析，先是跳到__main也就是0x08000130去执行，但是调试的时候，点击单步运行时，直接跳到__main_after_scatterload,当时就很纳闷，不应该啊，因为__main的值为0x08000131,后面再0x08000130处打了一个断点，就发现在断点处停住了，所以说编译器自动的略过了分散加载过程。直接跳到加载之后。

CMP是比较指令，r4-r5会更新APSR寄存器

BCC条件转移指令（C为0，即无进位有借位，则跳转），因为r4

接下来，取r4(0x8000b38)+0xc地址的内容赋给r0,即r0=08000ae0,调试也符合分析过程。

接着是ORR逻辑运算指令。代表的是将r3=r0|0x01,结果为r3=0x08000ae1

接着是LDM数据传送指令，LDM=LDMIA,从指定地址读取数据到寄存器列表中，地址自动增加,但是基址寄存器的内容不变。所以该行语句的意思是，从r4对应的地址处读数据到R0、R1、R2中，执行完后。

接下来BLX是跳转到R3对应的地址中去，这个指令会更新LR。

先是跳转到0x8000ae8,比较r2与0，不相等，跳转到0x08000ae2,加!代表的是会更新基址寄存器的值。读取r0地址的内容到r3中，然后是r2=r2-4，然后将r3的内容存储到r1对应的地址之中,r1也会自动增加，然后重复上述过程。知道r2=0,返回。
这个过程实际上就是拷贝flash中的RW数据区的内容读到SRAM中,这个0x08000B58就是节区2，如下图所示：

传输完成后，跳转到返回地址0x0800019e。
首先是相加指令ADDS(S代表更新标志位)，可得r4=r4+0x10。再次比较r4与r5,仍然是r4 然后是更新r0为0x08000af0,同样的r3=r0|0x01,然后从r4对应的地址处取值赋给r0、r1、r2，然后跳到r3处去执行。

这段代码和前面几乎一样，就是将SRAM的栈区全部初始化为0。然后返回。又再次返回到0x0800019e。

再次对r4执行加法运算，此时r4=r5,标志位C=1，BCC指令条件不成立，就跳转到__main_after_scatterload中去执行了。

到前面为止，已经弄好了，已经将RW数据区的数据复制到SRAM中了，并且将栈区的内容全部清零。接下来看看加载完成之后干了什么。

这两句很简单，前面已经遇到过 了，加载r0,然后跳到r0处去运行，即跳转到0x08000b01去执行。

到这里是真正进入主函数main中去执行，到这里为止，汇编代码就不再分析了。

2）总结进入main函数之前做了什么

主要就是完成分散加载的过程，将程序从存储时的样子变成运行时的样子。分散加载这个词看起来很抽象，其实就是一些copy工作。竖个中指给他，做CV我是专业的。
3)快速结束启动文件的尾巴

以其中一个为例。
NMI_Handler PROC
EXPORT NMI_Handler [WEAK]
B .
ENDP

上面就是不可屏蔽中断的处理过程，同样是弱定义的。这里B指令后加.就等同于无限循环，如下图所示：

其他的都类似，只不过编写格式有些不同，问题不大，知道是什么意思就行了。快进到用户栈和堆的初始化。
IF :DEF:__MICROLIB

EXPORT __initial_sp
EXPORT __heap_base
EXPORT __heap_limit

ELSE

IMPORT __use_two_region_memory
EXPORT __user_initial_stackheap

__user_initial_stackheap


LDR R0, = Heap_Mem
LDR R1, =(Stack_Mem + Stack_Size)
LDR R2, = (Heap_Mem + Heap_Size)
LDR R3, = Stack_Mem
BX LR


ALIGN


ENDIF


END

这里涉及到一个就是MicroLIB这个库，如果定义了这个宏__MICROLIB,在KEIL中可以勾选，如下图，就定义了这个宏，一般来说都会勾选的。

那什么是这个库呢？看官方的解释：

注意Note看库的功能。

结合代码来看，这个IF就相当于条件编译，如果定义了宏，前面不是汇编了堆栈段，就是使用这些段相关的符号。在前面讲解_main时用到了这些符号，包括，大小，起始地址。上面有一句话说，创建程序的运行环境，就是要有堆与栈。当程序在谈对象时，不就是要消耗堆与栈吗？

如果没有勾选，会怎么样呢？从代码上看，会IMPORT一个标号__use_two_region_memory，这个标号来自外部文件，来看看官方的解释：

简单点说，就是你要动手实现一大堆东西，这里不推荐。

到此，整个启动文件结束。

3)完整代码附录


Stack_Size EQU 0x400


AREA STACK, NOINIT, READWRITE, ALIGN=3
Stack_Mem SPACE Stack_Size
__initial_sp

; Heap Configuration
; Heap Size (in Bytes) <0x0-0xFFFFFFFF:8>
;

Heap_Size EQU 0x200


AREA HEAP, NOINIT, READWRITE, ALIGN=3
__heap_base
Heap_Mem SPACE Heap_Size
__heap_limit


PRESERVE8
THUMB




; Vector Table Mapped to Address 0 at Reset
AREA RESET, DATA, READONLY
EXPORT __Vectors
EXPORT __Vectors_End
EXPORT __Vectors_Size


__Vectors DCD __initial_sp ; Top of Stack
DCD Reset_Handler ; Reset Handler
DCD NMI_Handler ; NMI Handler
DCD HardFault_Handler ; Hard Fault Handler
DCD MemManage_Handler ; MPU Fault Handler
DCD BusFault_Handler ; Bus Fault Handler
DCD UsageFault_Handler ; Usage Fault Handler
DCD 0 ; Reserved
DCD 0 ; Reserved
DCD 0 ; Reserved
DCD 0 ; Reserved
DCD SVC_Handler ; SVCall Handler
DCD DebugMon_Handler ; Debug Monitor Handler
DCD 0 ; Reserved
DCD PendSV_Handler ; PendSV Handler
DCD SysTick_Handler ; SysTick Handler


; External Interrupts
DCD WWDG_IRQHandler ; Window Watchdog
DCD PVD_IRQHandler ; PVD through EXTI Line detect
DCD TAMPER_IRQHandler ; Tamper
DCD RTC_IRQHandler ; RTC
DCD FLASH_IRQHandler ; Flash
DCD RCC_IRQHandler ; RCC
DCD EXTI0_IRQHandler ; EXTI Line 0
DCD EXTI1_IRQHandler ; EXTI Line 1
DCD EXTI2_IRQHandler ; EXTI Line 2
DCD EXTI3_IRQHandler ; EXTI Line 3
DCD EXTI4_IRQHandler ; EXTI Line 4
DCD DMA1_Channel1_IRQHandler ; DMA1 Channel 1
DCD DMA1_Channel2_IRQHandler ; DMA1 Channel 2
DCD DMA1_Channel3_IRQHandler ; DMA1 Channel 3
DCD DMA1_Channel4_IRQHandler ; DMA1 Channel 4
DCD DMA1_Channel5_IRQHandler ; DMA1 Channel 5
DCD DMA1_Channel6_IRQHandler ; DMA1 Channel 6
DCD DMA1_Channel7_IRQHandler ; DMA1 Channel 7
DCD ADC1_2_IRQHandler ; ADC1 & ADC2
DCD USB_HP_CAN1_TX_IRQHandler ; USB High Priority or CAN1 TX
DCD USB_LP_CAN1_RX0_IRQHandler ; USB Low Priority or CAN1 RX0
DCD CAN1_RX1_IRQHandler ; CAN1 RX1
DCD CAN1_SCE_IRQHandler ; CAN1 SCE
DCD EXTI9_5_IRQHandler ; EXTI Line 9..5
DCD TIM1_BRK_IRQHandler ; TIM1 Break
DCD TIM1_UP_IRQHandler ; TIM1 Update
DCD TIM1_TRG_COM_IRQHandler ; TIM1 Trigger and Commutation
DCD TIM1_CC_IRQHandler ; TIM1 Capture Compare
DCD TIM2_IRQHandler ; TIM2
DCD TIM3_IRQHandler ; TIM3
DCD TIM4_IRQHandler ; TIM4
DCD I2C1_EV_IRQHandler ; I2C1 Event
DCD I2C1_ER_IRQHandler ; I2C1 Error
DCD I2C2_EV_IRQHandler ; I2C2 Event
DCD I2C2_ER_IRQHandler ; I2C2 Error
DCD SPI1_IRQHandler ; SPI1
DCD SPI2_IRQHandler ; SPI2
DCD USART1_IRQHandler ; USART1
DCD USART2_IRQHandler ; USART2
DCD USART3_IRQHandler ; USART3
DCD EXTI15_10_IRQHandler ; EXTI Line 15..10
DCD RTC_Alarm_IRQHandler ; RTC Alarm through EXTI Line
DCD USBWakeUp_IRQHandler ; USB Wakeup from suspend
DCD TIM8_BRK_IRQHandler ; TIM8 Break
DCD TIM8_UP_IRQHandler ; TIM8 Update
DCD TIM8_TRG_COM_IRQHandler ; TIM8 Trigger and Commutation
DCD TIM8_CC_IRQHandler ; TIM8 Capture Compare
DCD ADC3_IRQHandler ; ADC3
DCD FSMC_IRQHandler ; FSMC
DCD SDIO_IRQHandler ; SDIO
DCD TIM5_IRQHandler ; TIM5
DCD SPI3_IRQHandler ; SPI3
DCD UART4_IRQHandler ; UART4
DCD UART5_IRQHandler ; UART5
DCD TIM6_IRQHandler ; TIM6
DCD TIM7_IRQHandler ; TIM7
DCD DMA2_Channel1_IRQHandler ; DMA2 Channel1
DCD DMA2_Channel2_IRQHandler ; DMA2 Channel2
DCD DMA2_Channel3_IRQHandler ; DMA2 Channel3
DCD DMA2_Channel4_5_IRQHandler ; DMA2 Channel4 & Channel5
__Vectors_End


__Vectors_Size EQU __Vectors_End - __Vectors


AREA |.text|, CODE, READONLY

; Reset handler
Reset_Handler PROC
EXPORT Reset_Handler [WEAK]
IMPORT __main
IMPORT SystemInit
LDR R0, =SystemInit
BLX R0
LDR R0, =__main
BX R0
ENDP

; Dummy Exception Handlers (infinite loops which can be modified)


NMI_Handler PROC
EXPORT NMI_Handler [WEAK]
B .
ENDP
HardFault_Handler
PROC
EXPORT HardFault_Handler [WEAK]
B .
ENDP
MemManage_Handler
PROC
EXPORT MemManage_Handler [WEAK]
B .
ENDP
BusFault_Handler
PROC
EXPORT BusFault_Handler [WEAK]
B .
ENDP
UsageFault_Handler
PROC
EXPORT UsageFault_Handler [WEAK]
B .
ENDP
SVC_Handler PROC
EXPORT SVC_Handler [WEAK]
B .
ENDP
DebugMon_Handler
PROC
EXPORT DebugMon_Handler [WEAK]
B .
ENDP
PendSV_Handler PROC
EXPORT PendSV_Handler [WEAK]
B .
ENDP
SysTick_Handler PROC
EXPORT SysTick_Handler [WEAK]
B .
ENDP


Default_Handler PROC


EXPORT WWDG_IRQHandler [WEAK]
EXPORT PVD_IRQHandler [WEAK]
EXPORT TAMPER_IRQHandler [WEAK]
EXPORT RTC_IRQHandler [WEAK]
EXPORT FLASH_IRQHandler [WEAK]
EXPORT RCC_IRQHandler [WEAK]
EXPORT EXTI0_IRQHandler [WEAK]
EXPORT EXTI1_IRQHandler [WEAK]
EXPORT EXTI2_IRQHandler [WEAK]
EXPORT EXTI3_IRQHandler [WEAK]
EXPORT EXTI4_IRQHandler [WEAK]
EXPORT DMA1_Channel1_IRQHandler [WEAK]
EXPORT DMA1_Channel2_IRQHandler [WEAK]
EXPORT DMA1_Channel3_IRQHandler [WEAK]
EXPORT DMA1_Channel4_IRQHandler [WEAK]
EXPORT DMA1_Channel5_IRQHandler [WEAK]
EXPORT DMA1_Channel6_IRQHandler [WEAK]
EXPORT DMA1_Channel7_IRQHandler [WEAK]
EXPORT ADC1_2_IRQHandler [WEAK]
EXPORT USB_HP_CAN1_TX_IRQHandler [WEAK]
EXPORT USB_LP_CAN1_RX0_IRQHandler [WEAK]
EXPORT CAN1_RX1_IRQHandler [WEAK]
EXPORT CAN1_SCE_IRQHandler [WEAK]
EXPORT EXTI9_5_IRQHandler [WEAK]
EXPORT TIM1_BRK_IRQHandler [WEAK]
EXPORT TIM1_UP_IRQHandler [WEAK]
EXPORT TIM1_TRG_COM_IRQHandler [WEAK]
EXPORT TIM1_CC_IRQHandler [WEAK]
EXPORT TIM2_IRQHandler [WEAK]
EXPORT TIM3_IRQHandler [WEAK]
EXPORT TIM4_IRQHandler [WEAK]
EXPORT I2C1_EV_IRQHandler [WEAK]
EXPORT I2C1_ER_IRQHandler [WEAK]
EXPORT I2C2_EV_IRQHandler [WEAK]
EXPORT I2C2_ER_IRQHandler [WEAK]
EXPORT SPI1_IRQHandler [WEAK]
EXPORT SPI2_IRQHandler [WEAK]
EXPORT USART1_IRQHandler [WEAK]
EXPORT USART2_IRQHandler [WEAK]
EXPORT USART3_IRQHandler [WEAK]
EXPORT EXTI15_10_IRQHandler [WEAK]
EXPORT RTC_Alarm_IRQHandler [WEAK]
EXPORT USBWakeUp_IRQHandler [WEAK]
EXPORT TIM8_BRK_IRQHandler [WEAK]
EXPORT TIM8_UP_IRQHandler [WEAK]
EXPORT TIM8_TRG_COM_IRQHandler [WEAK]
EXPORT TIM8_CC_IRQHandler [WEAK]
EXPORT ADC3_IRQHandler [WEAK]
EXPORT FSMC_IRQHandler [WEAK]
EXPORT SDIO_IRQHandler [WEAK]
EXPORT TIM5_IRQHandler [WEAK]
EXPORT SPI3_IRQHandler [WEAK]
EXPORT UART4_IRQHandler [WEAK]
EXPORT UART5_IRQHandler [WEAK]
EXPORT TIM6_IRQHandler [WEAK]
EXPORT TIM7_IRQHandler [WEAK]
EXPORT DMA2_Channel1_IRQHandler [WEAK]
EXPORT DMA2_Channel2_IRQHandler [WEAK]
EXPORT DMA2_Channel3_IRQHandler [WEAK]
EXPORT DMA2_Channel4_5_IRQHandler [WEAK]


WWDG_IRQHandler
PVD_IRQHandler
TAMPER_IRQHandler
RTC_IRQHandler
FLASH_IRQHandler
RCC_IRQHandler
EXTI0_IRQHandler
EXTI1_IRQHandler
EXTI2_IRQHandler
EXTI3_IRQHandler
EXTI4_IRQHandler
DMA1_Channel1_IRQHandler
DMA1_Channel2_IRQHandler
DMA1_Channel3_IRQHandler
DMA1_Channel4_IRQHandler
DMA1_Channel5_IRQHandler
DMA1_Channel6_IRQHandler
DMA1_Channel7_IRQHandler
ADC1_2_IRQHandler
USB_HP_CAN1_TX_IRQHandler
USB_LP_CAN1_RX0_IRQHandler
CAN1_RX1_IRQHandler
CAN1_SCE_IRQHandler
EXTI9_5_IRQHandler
TIM1_BRK_IRQHandler
TIM1_UP_IRQHandler
TIM1_TRG_COM_IRQHandler
TIM1_CC_IRQHandler
TIM2_IRQHandler
TIM3_IRQHandler
TIM4_IRQHandler
I2C1_EV_IRQHandler
I2C1_ER_IRQHandler
I2C2_EV_IRQHandler
I2C2_ER_IRQHandler
SPI1_IRQHandler
SPI2_IRQHandler
USART1_IRQHandler
USART2_IRQHandler
USART3_IRQHandler
EXTI15_10_IRQHandler
RTC_Alarm_IRQHandler
USBWakeUp_IRQHandler
TIM8_BRK_IRQHandler
TIM8_UP_IRQHandler
TIM8_TRG_COM_IRQHandler
TIM8_CC_IRQHandler
ADC3_IRQHandler
FSMC_IRQHandler
SDIO_IRQHandler
TIM5_IRQHandler
SPI3_IRQHandler
UART4_IRQHandler
UART5_IRQHandler
TIM6_IRQHandler
TIM7_IRQHandler
DMA2_Channel1_IRQHandler
DMA2_Channel2_IRQHandler
DMA2_Channel3_IRQHandler
DMA2_Channel4_5_IRQHandler
B .


ENDP


ALIGN


;*******************************************************************************
; User Stack and Heap initialization
;*******************************************************************************
IF :DEF:__MICROLIB

EXPORT __initial_sp
EXPORT __heap_base
EXPORT __heap_limit

ELSE

IMPORT __use_two_region_memory
EXPORT __user_initial_stackheap

__user_initial_stackheap


LDR R0, = Heap_Mem
LDR R1, =(Stack_Mem + Stack_Size)
LDR R2, = (Heap_Mem + Heap_Size)
LDR R3, = Stack_Mem
BX LR


ALIGN


ENDIF


END
F:__MICROLIB


EXPORT __initial_sp
EXPORT __heap_base
EXPORT __heap_limit

ELSE

IMPORT __use_two_region_memory
EXPORT __user_initial_stackheap
__user_initial_stackheap


LDR R0, = Heap_Mem
LDR R1, =(Stack_Mem + Stack_Size)
LDR R2, = (Heap_Mem + Heap_Size)
LDR R3, = Stack_Mem
BX LR


ALIGN


ENDIF


END