资料下载
如何在Arduino中使用NRF24L01模块
123
分享资料个
描述
主条目：如何在 Arduino 中使用 NRF24L01 模块
拥有两个或多个 Arduino 板能够在一定距离内以无线方式相互通信打开了许多可能性，例如远程监控传感器数据、控制机器人、家庭自动化等等。NRF24L01 是一种良好、可靠且廉价的解决方案。
NRF24L01+ 是 NRF24L01 的更新版本，能够额外提供 250kbps 的空中数据速率，而没有“+”的只有 1Mbps 和 2Mbps。只要使用 1 或 2 MBps 作为数据速率，两个版本都可以混合使用。
NRF24L01 与 NRF24L01+PA+LNA
NRF24L01 模块严格需要 3.3V，但逻辑引脚可承受 5V。这就是为什么我们推荐使用 NRF24L01 适配器作为稳压器，保持电压稳定，应用滤波和降低噪音。
第一个版本（左侧）使用板载天线。这允许更紧凑的突破版本。使用此版本，您将能够在 100 米的距离内进行通信（室内范围，尤其是穿过墙壁，将略微减弱）。我们将它用于接收器。
第二个版本（右侧）集成了 PA、LNA 和收发切换电路。该范围扩展芯片与外部天线一起帮助模块达到约 1000m。我们将它用于发射器。
该适配器对两个版本的工作方式相同，并且具有与原始板相同的引脚排列。
接线图
NRF24L01 模块使用 SPI 协议与 Arduino 通信。该模块充当 SPI 从机，这意味着它只能与具有专用 SPI 通信线路的设备一起使用。这意味着MOSI 、MISO和SCK引脚必须连接到微控制器上相应的引脚。我们使用了 Arduino Nano，这些引脚如下：
- MOSI ：Arduino Nano D11
- 味噌：Arduino Nano D12
- SCK : Arduino Nano D13
CE和CSN引脚可以分别连接到 Arduino Nano D9 和 D10（您可以使用任何引脚）。但是，D10 引脚是一个特殊引脚，必须将其设置为OUTPUT才能使Arduino Nano作为 SPI 主机运行。如果您使用不同的 Arduino 板，建议在继续之前查看Arduino 官方文档。
注意：您需要制作两个这样的电路。一个充当发射器，另一个充当接收器。两者的接线是相同的。
为 nRF24L01 安装 Arduino 库
该库将为您提供与模块进行通信的接口，从而为您节省大量时间，并提供经过社区多年测试和改进的强大代码库。您可以从我们的官方存储库下载该库。
要导入它，请打开 Arduino IDE，转到 Sketch > Include Library > Add.ZIP Library，然后选择刚刚下载的文件。
然后你可以简单地使用include语句：
#include "RF24.h"
#include "nRF24L01.h"
它将包含具有与模块交互的预定义函数的库。
发射器 Arduino 代码
我们定义了一个结构（称为payload ），它将每INTERVAL_MS_TRANSMISSION毫秒发送一次。
- setup()函数使用提供的配置启动模块作为发送器。
- loop()函数将负责更新有效负载值并发送它们。
#include "SPI.h"
#include "RF24.h"
#include "nRF24L01.h"
#define CE_PIN 9
#define CSN_PIN 10
#define INTERVAL_MS_TRANSMISSION 250
RF24 radio(CE_PIN, CSN_PIN);
const byte address[6] = "00001";
//NRF24L01 buffer limit is 32 bytes (max struct size)
struct payload {
byte data1;
char data2;
};
payload payload;
void setup()
{
Serial.begin(115200);
radio.begin();
//Append ACK packet from the receiving radio back to the transmitting radio
radio.setAutoAck(false); //(true|false)
//Set the transmission datarate
radio.setDataRate(RF24_250KBPS); //(RF24_250KBPS|RF24_1MBPS|RF24_2MBPS)
//Greater level = more consumption = longer distance
radio.setPALevel(RF24_PA_MAX); //(RF24_PA_MIN|RF24_PA_LOW|RF24_PA_HIGH|RF24_PA_MAX)
//Default value is the maximum 32 bytes
radio.setPayloadSize(sizeof(payload));
//Act as transmitter
radio.openWritingPipe(address);
radio.stopListening();
}
void loop()
{
payload.data1 = 123;
payload.data2 = 'x';
radio.write(&payload, sizeof(payload));
Serial.print("Data1:");
Serial.println(payload.data1);
Serial.print("Data2:");
Serial.println(payload.data2);
Serial.println("Sent");
delay(INTERVAL_MS_TRANSMISSION);
}
接收器 Arduino 代码
我们将监听发送器中定义的结构（称为payload ）。在INTERVAL_MS_SIGNAL_LOST毫秒后，连接将被视为丢失。
- setup()函数使用提供的配置启动模块作为接收器。
- loop()函数将负责侦听有效负载并进行处理。
- lostConnection()函数将处理丢失的连接以防止不必要的行为。
#include "SPI.h"
#include "RF24.h"
#include "nRF24L01.h"
#define CE_PIN 9
#define CSN_PIN 10
#define INTERVAL_MS_SIGNAL_LOST 1000
#define INTERVAL_MS_SIGNAL_RETRY 250
RF24 radio(CE_PIN, CSN_PIN);
const byte address[6] = "00001";
//NRF24L01 buffer limit is 32 bytes (max struct size)
struct payload {
byte data1;
char data2;
};
payload payload;
unsigned long lastSignalMillis = 0;
void setup()
{
Serial.begin(115200);
radio.begin();
//Append ACK packet from the receiving radio back to the transmitting radio
radio.setAutoAck(false); //(true|false)
//Set the transmission datarate
radio.setDataRate(RF24_250KBPS); //(RF24_250KBPS|RF24_1MBPS|RF24_2MBPS)
//Greater level = more consumption = longer distance
radio.setPALevel(RF24_PA_MIN); //(RF24_PA_MIN|RF24_PA_LOW|RF24_PA_HIGH|RF24_PA_MAX)
//Default value is the maximum 32 bytes1
radio.setPayloadSize(sizeof(payload));
//Act as receiver
radio.openReadingPipe(0, address);
radio.startListening();
}
void loop()
{
unsigned long currentMillis = millis();
if (radio.available() > 0) {
radio.read(&payload, sizeof(payload));
Serial.println("Received");
Serial.print("Data1:");
Serial.println(payload.data1);
Serial.print("Data2:");
Serial.println(payload.data2);
lastSignalMillis = currentMillis;
}
if (currentMillis - lastSignalMillis > INTERVAL_MS_SIGNAL_LOST) {
lostConnection();
}
}
void lostConnection()
{
Serial.println("We have lost connection, preventing unwanted behavior");
delay(INTERVAL_MS_SIGNAL_RETRY);
}
测试
请记住，我们必须构建两个具有相同接线的电路。
一方面，我们将上传发射器代码。它将生成消息有效负载并在每个INTERVAL_MS_TRANSMISSION发送它。
另一方面，我们将上传接收方代码。它将侦听消息有效负载并进行处理。串行监视器将输出类似于：
最后一行表示连接丢失（在没有信号的INTERVAL_MS_SIGNAL_LOST毫秒之后）。在我们的例子中，这是一种预期的行为。在现实生活中，由于许多已知和未知的原因，信号可能会丢失，我们应该能够控制它并采取纠正措施（在lostConnection()函数中）。
声明：本文内容及配图由入驻作者撰写或者入驻合作网站授权转载。文章观点仅代表作者本人，不代表德赢Vwin官网 网立场。文章及其配图仅供工程师学习之用，如有内容侵权或者其他违规问题，请联系本站处理。 举报投诉
- 相关下载
- 相关文章
